home *** CD-ROM | disk | FTP | other *** search
/ Gold Medal Software 2 / Gold Medal Software Volume 2 (Gold Medal) (1994).iso / prog / asm_0_m.arj / KWIKKEY.ASM < prev    next >
Assembly Source File  |  1986-07-01  |  11KB  |  255 lines
  1. ;----------------------------------------------------------------- 
  2. ; KWIKKEY.ASM  Version 1.4                                  5-28-86 
  3. ; Copyright (c) 1985 by Dan Rollins    
  4. ; 
  5. ; This program speeds up the repeat action of the IBM PC and XT 
  6. ; keyboard. After installation, a keystroke begins repeating about 
  7. ; 1/4 second after the initial keystroke and the repeats occur at 
  8. ; about twice the normal speed. These delay and rate parameters may 
  9. ; be modified. The program uses the 55ms timer interrupt to augment 
  10. ; the speed of the keyboard. The basic idea is to have the timer 
  11. ; interrupt check to see if the key has been released. If not, then 
  12. ; it stuffs a keystroke into the BIOS keyboard buffer. Notes: This 
  13. ; program must be used with DOS 2.x or later.  It is a COM format 
  14. ; program, so it must be processed by EXE2BIN. 
  15. ;------------------------------------------------------------------
  16. ;=== program equates ===
  17.  
  18. REPT_DELAY    equ     5  ;number of 55ms intervals to skip before
  19.                          ; the first repeat.  5 = 275ms = about 
  20.                          ; 1/4 second.   Use at least 2 to avoid 
  21.              ; "key bounce"
  22.  
  23. REPT_RATE     equ     1  ;Select from:   0 = 29 repeats per second
  24.                          ;               1 = 20 repeats per second
  25.                          ;               2 = 16 repeats per second
  26.                          ;               3 = 13 repeats per second
  27.                          ;       4 or more = standard repeat rate
  28.  
  29. BIOS_DATA_SEG equ     40h  ;These addresses are listed
  30. BUF_START     equ     1eh  ; in the Technical Reference manual
  31. BUF_END       equ     3eh
  32. BUF_HEAD_ADDR equ     1ah
  33. BUF_TAIL_ADDR equ     1ch
  34. ALT_NUM_BUF   equ     19h
  35.  
  36. FALSE         equ     0
  37. TRUE          equ     1
  38.  
  39. ;=========================
  40.  
  41. com_seg  segment
  42.          assume  cs:com_seg, ds:com_seg
  43.          org     100h                    ;must set up for COM file
  44. kwikkey  proc    far
  45.          jmp     set_up    ;get past the data and install the
  46.                            ;interrupt handlers
  47.  
  48. ;============= program data area ========
  49. delay          db    REPT_DELAY  ;max ticks BEFORE STARTING to repeat
  50. rate           db    REPT_RATE   ;maximum ticks BETWEEN repeats
  51.  
  52. inst_flag      dw    1234h   ;KWIKKEY signature when already installed
  53.  
  54. rep_ok         db    FALSE   ;flag turns off repeat while processing
  55. last_key       dw    0       ;stores most recent keyboard scan code
  56.  
  57. init_delay     db    REPT_DELAY  ;remaining ticks before 
  58.                             ;starting to repeat
  59. rate_delay     db    REPT_RATE   ;remaining tick between repeats
  60.  
  61. bios_kbd_int   label dword   ;DWORD so it can be used in a FAR call
  62. bki_offset     dw    0       ; This is set to the addr of BIOS KB_INT
  63. bki_segment    dw    0       ; at the time of installation of KWIKKEY
  64.  
  65. user_timer_int label  dword  ;used to preserve "forward chain" of user
  66. uti_offset     dw    0       ;timer interrupt handlers.  Set in SET_UP
  67. uti_segment    dw    0       ;procedure, this addr will normally point 
  68.                              ;to an IRET.
  69.  
  70.  
  71. ;---------------------------------------------------------------------
  72. ; KBD_INT
  73. ; This procedure intercepts keystrokes and sends control to normal 
  74. ; BIOS KB_INT.  Its primary function is to set up for the repeat action 
  75. ; that occurs in the TIMER_INT.  It checks each key that comes in, and
  76. ; resets a delay counter if it is a new keystroke.
  77.  
  78. kbd_int  proc    far
  79.          mov     cs:rep_ok,FALSE       ;turn off repeats while 
  80.                     ;processing
  81.          push    ax                    ;save the registers
  82.          push    si
  83.          push    ds
  84.          mov     ax,BIOS_DATA_SEG      ; set up to address 
  85.          mov     ds,ax                 ; BIOS data area
  86.          mov     si,ds:[BUF_TAIL_ADDR] ;get addr of current 
  87.                     ;buffer tail
  88.  
  89.         ;check special case: don't repeat ALT-numpad keystrokes
  90.  
  91.          cmp     byte ptr ds:[ALT_NUM_BUF],0 ;is one in progress?
  92.          je      ki_10                       ; no, continue
  93.          pushf                               ; yes, process 
  94.          call    cs:bios_kbd_int             ; the keystroke
  95.          jmp     ki_exit                     ; exit with repeats off
  96. ki_10:
  97.          pushf                          ;simulate a normal interrupt
  98.          call    cs:bios_kbd_int        ; and process the keystroke
  99.  
  100.          cmp     si,ds:[BUF_TAIL_ADDR]  ;did the tail move?
  101.          jne     ki_20                  ; no, either a shift-key 
  102.                     ; or a release
  103.          mov     cs:last_key,0          ; insure no spurious repeats
  104.          jmp     ki_exit                ; exit with repeats turned off
  105. ki_20:                                  ; yes, process the keystroke
  106.          mov     ax,[si]                ; get new scan code
  107.          cmp     ax,cs:[last_key]       ; same as last time?
  108.          mov     cs:last_key,ax         ; (save the key for next time)
  109.          je      ki_30                  ;  yes, hardware repeat 
  110.                                         ;       just reset the rate
  111.                                         ;  no, reset both timer delays
  112.          mov     al,cs:delay            ;  get maximum tick count
  113.          mov     cs:init_delay,al       ;  set delay before repeat
  114. ki_30:
  115.          mov     al,cs:rate             ;    get maximum tick value
  116.          mov     cs:rate_delay,al       ;    set delay between repeats
  117.          mov     cs:rep_ok,TRUE         ;  OK to continue repeating
  118.  
  119. ki_exit:
  120.          pop     ds
  121.          pop     si
  122.          pop     ax
  123.          iret                     ;also restores Flags of interruptee
  124. kbd_int  endp
  125.  
  126.  
  127. ;---------------------------------------------------------------------
  128. ; TIMER_INT
  129. ; This procedure is executed 18.2 times per second
  130. ;
  131. ; It checks to see if a repeat is needed.  If so, it stuffs the scan 
  132. ; code into the keyboard buffer, ready for the next keystroke request
  133. ;
  134. timer_int proc far
  135.          cmp     cs:[rep_ok],TRUE    ;are repeats blocked?
  136.          jne     ti_exit             ;   yes, resume without repeat
  137.  
  138.          cmp     cs:init_delay,0   ;finished delaying before 
  139.                 ;first repeat?
  140.          je      ti_10             ;   yes, check rate delay
  141.          dec     cs:init_delay     ;   no, decrement timer
  142.          jmp     ti_exit           ;       and resume without repeat
  143.  
  144. ti_10:
  145.          cmp     cs:rate_delay,0   ;finished delaying between repeats?
  146.          je      ti_20             ;   yes, do the repeat
  147.          dec     cs:rate_delay     ;   no, decrement rate timer
  148.          jmp     ti_exit           ;       and resume without repeat
  149.  
  150. ;------- repeat the previous keystroke -----------
  151.  
  152. ti_20:
  153.          push    ax                     ;save all registers used
  154.          push    si
  155.          push    ds
  156.  
  157.          mov     ax,BIOS_DATA_SEG  ;prepare to address BIOS data area
  158.          mov     ds,ax
  159.          mov     ax,ds:[BUF_TAIL_ADDR]  ;get current position 
  160.                     ;in kbd buffer
  161.          mov     si,ax                  ;we'll need this address later
  162.          add     ax,2                   ;point to next position in buffer
  163.          cmp     ax,BUF_END             ;past end of buffer?
  164.          jne     ti_30                  ;  no, continue
  165.          mov     ax,BUF_START           ;  yes, next position is the 
  166.                                         ;start
  167. ti_30:
  168.          cmp     ax,ds:[BUF_HEAD_ADDR]  ;if tail=head, buffer is full
  169.          je      ti_40                  ;full, continue without repeat
  170.          cli                            ;not full, dont allow break-in
  171.          mov     ds:[BUF_TAIL_ADDR],ax  ;      update buffer position
  172.          mov     ax,cs:[last_key]       ;      fetch key to repeat
  173.          mov     [si],ax                ;      store key in buffer
  174.          sti                            ;      interrupts ok now
  175. ti_40:
  176.          mov     al,cs:rate             ;get the max rate delay value
  177.          mov     cs:rate_delay,al       ;don't repeat for a while
  178.          pop     ds                     ;restore registers
  179.          pop     si                     ; and exit
  180.          pop     ax
  181. ti_exit:
  182.          jmp     cs:[user_timer_int]    ;continue with previously 
  183.                                         ;installed interrupt handler 
  184. timer_int endp
  185.  
  186. LAST_BYTE equ   offset $+1  ;this is the address passed to INT 27H
  187.                             ; Notice that the code of the SET_UP
  188.                             ; procedure does not need to be preserved
  189.  
  190. ;---------------------------------------------------------------------
  191. ; SET_UP
  192. ; This routine is executed only once -- when the program is installed.
  193. ;
  194. ; It resets the vectors of the KBD_INT and the USER_TIMER_INT, 
  195. ; pointing them to code within this program.  Note that the original 
  196. ; vectors are saved and executed so all previously-installed interrupt
  197. ; handlers remain operational.
  198.  
  199. logo_msg db 201, 25 dup(205),187,0dh,0ah
  200.          db 186,'    KWIKKEY  Ver. 1.4    ',186,0dh,0ah
  201.          db 186,' (c) 1986 by Dan Rollins ',186,0dh,0ah
  202.          db 200, 25 dup(205),188,0dh,0ah,'$'
  203.  
  204. err_msg  db 'Error: ',07,'KWIKKEY already installed',0dh,0ah,'$'
  205.  
  206. set_up   proc    near
  207.          ;------ first, make sure KWIKKEY hasn't been installed ---
  208.          mov     al,9
  209.          mov     ah,35h              ;DOS GET_VECTOR service
  210.          int     21h                 ; for interrupt 9
  211.  
  212.          cmp     es:inst_flag,1234h  ;has KWIKKEY been installed?
  213.          jne     su_10               ; no, continue
  214.          mov     dx,offset err_msg   ; yes, display
  215.          mov     ah,9                ;       error
  216.          int     21h                 ;        message
  217.          int     20h                 ;and exit to DOS
  218. su_10:
  219.          mov     al,9           ;get original vector of keyboard int 9
  220.          mov     ah,35h         ;DOS GET_VECTOR service
  221.          int     21h
  222.          mov     bki_segment,es ;save original address
  223.          mov     bki_offset,bx  ; so we can resume normally 
  224.                           ; after intercept
  225.          mov     dx,offset kbd_int
  226.          mov     al,9           ;set vector for INT 9
  227.          mov     ah,25h         ;DOS SET_VECTOR service
  228.          int     21h
  229.  
  230.          mov     al,1ch         ;the user timer interrupt
  231.          mov     ah,35h         ;DOS GET_VECTOR service
  232.          int     21h
  233.          mov     uti_segment,es ;save old address
  234.          mov     uti_offset,bx  ; so we don't hog the timer interrupt
  235.  
  236.          mov     dx,offset timer_int
  237.          mov     al,1ch        ;set vector to point to new TIMER_INT
  238.          mov     ah,25h        ;DOS SET_VECTOR service
  239.          int     21h
  240.  
  241.          ;------ display logo to indicate installation complete
  242.          mov     dx,offset logo_msg
  243.          mov     ah,9
  244.          int     21h
  245.  
  246.          mov     cs:rep_ok,TRUE   ; it's OK to start repeat action
  247.  
  248.          ;------ exit to DOS, leaving the interrupt handlers resident
  249.          mov     dx,LAST_BYTE
  250.          int     27h
  251. set_up   endp
  252. kwikkey  endp
  253. com_seg  ends
  254.          end     kwikkey       ;must specify for COM-format file
  255.